add candy-kingdom sat solver pkgbuild

1 files changed, 38 insertions, 0 deletions

diff --git a/candy-kingdom-git/PKGBUILD b/candy-kingdom-git/PKGBUILD
new file mode 100644
index 0000000..0952ffb
--- /dev/null
+++ b/candy-kingdom-git/PKGBUILD
@@ -0,0 +1,38 @@
+pkgname=candy-kingdom-git
+_pkgname=candy-kingdom
+pkgver=1388
+pkgrel=1
+pkgdesc="A collection of SAT solvers and tools for structure analysis in SAT problems."
+arch=("any")
+url="https://github.com/Udopia/candy-kingdom"
+license=("MIT")
+makedepends=("cmake" "git")
+source=(
+    "${_pkgname}::git+https://github.com/Udopia/candy-kingdom.git#branch=master"
+)
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "${_pkgname}"
+    git rev-list --count HEAD
+}
+
+prepare() {
+    cd "${_pkgname}"
+    git submodule init
+    git submodule set-url -- lib/oscpack https://github.com/Udopia/oscpack.git
+    git submodule update
+}
+
+build() {
+    mkdir -p "${_pkgname}/build"
+    cd "${_pkgname}/build"
+    cmake -DCMAKE_BUILD_TYPE=Release ..
+    make candy
+}
+
+package() {
+    cd "${_pkgname}/build"
+    install -Dm 755 candy "${pkgdir}/usr/bin/candy"
+    install -Dm 644 libcandylib.a "${pkgdir}/usr/lib/libcandylib.a"
+}