use super::{
    FError,
    FErrorKind,
    FightOutcome,
    filters,
    SearchField,
    Weekday,
};
use evtclib::statistics::gamedata::Boss;
use std::collections::HashSet;
use lalrpop_util::ParseError;

use chrono::NaiveDateTime;
use regex::Regex;

grammar;

extern {
    type Error = FError;
}

pub LogFilter: Box<dyn filters::log::LogFilter> = {
    Disjunction<LogPredicate>,
}

PlayerFilter: Box<dyn filters::player::PlayerFilter> = {
    Disjunction<PlayerPredicate>,
}

Disjunction<T>: T = {
    <a:Disjunction<T>> "or" <b:Conjunction<T>> => a | b,
    Conjunction<T>,
}

Conjunction<T>: T = {
    <a:Conjunction<T>> "and"? <b:Negation<T>> => a & b,
    Negation<T>,
}

Negation<T>: T = {
    "not" <Negation<T>> => ! <>,
    "!" <Negation<T>> => ! <>,
    T,
}

LogPredicate: Box<dyn filters::log::LogFilter> = {
    "-success" => filters::log::OutcomeFilter::success(),
    "-wipe" => filters::log::OutcomeFilter::wipe(),
    "-outcome" <Comma<FightOutcome>> => filters::log::OutcomeFilter::new(<>),

    "-weekday" <Comma<Weekday>> => filters::log::WeekdayFilter::new(<>),
    "-before" <Date> => filters::log::TimeFilter::new(None, Some(<>)),
    "-after" <Date> => filters::log::TimeFilter::new(Some(<>), None),

    "-boss" <Comma<Boss>> => filters::log::BossFilter::new(<>),

    "-player" <Regex> => filters::player::any(
            filters::player::NameFilter::new(SearchField::Character, <>.clone())
            | filters::player::NameFilter::new(SearchField::Account, <>)
        ),

    "all" "(" "player" ":" <PlayerFilter> ")" => filters::player::all(<>),
    "any" "(" "player" ":" <PlayerFilter> ")" => filters::player::any(<>),
    "exists" "(" "player" ":" <PlayerFilter> ")" => filters::player::any(<>),

    "(" <LogFilter> ")",
}

PlayerPredicate: Box<dyn filters::player::PlayerFilter> = {
    "-character" <Regex> => filters::player::NameFilter::new(SearchField::Character, <>),
    "-account" <Regex> => filters::player::NameFilter::new(SearchField::Account, <>),
    "-name" <Regex> =>
        filters::player::NameFilter::new(SearchField::Account, <>.clone())
        | filters::player::NameFilter::new(SearchField::Character, <>),

    "(" <PlayerFilter> ")",
}

Regex: Regex = {
    <l:@L> <s:regex> =>? Regex::new(&s[1..s.len() - 1]).map_err(|error| ParseError::User {
        error: FError {
            location: l,
            data: s.to_string(),
            kind: error.into(),
        }
    }),
    <l:@L> <s:word> =>? Regex::new(s).map_err(|error| ParseError::User {
        error: FError {
            location: l,
            data: s.to_string(),
            kind: error.into(),
        }
    }),
}

FightOutcome: FightOutcome = {
    <l:@L> <w:word> =>? w.parse().map_err(|_| ParseError::User {
        error: FError {
            location: l,
            data: w.into(),
            kind: FErrorKind::InvalidFightOutcome,
        }
    }),
}

Weekday: Weekday = {
    <l:@L> <w:word> =>? w.parse().map_err(|_| ParseError::User {
        error: FError {
            location: l,
            data: w.into(),
            kind: FErrorKind::InvalidWeekday,
        }
    }),
}

Boss: Boss = {
    <l:@L> <w:word> =>? w.parse().map_err(|_| ParseError::User {
        error: FError {
            location: l,
            data: w.into(),
            kind: FErrorKind::InvalidBoss,
        }
    }),
}

Date: NaiveDateTime = {
    <l:@L> <d:datetime> =>? NaiveDateTime::parse_from_str(d, "%Y-%m-%d %H:%M:%S")
        .map_err(|error| ParseError::User {
            error: FError {
                location: l,
                data: d.into(),
                kind: error.into(),
            }
        }),
    <l:@L> <d:date> =>? NaiveDateTime::parse_from_str(&format!("{} 00:00:00", d), "%Y-%m-%d %H:%M:%S")
        .map_err(|error| ParseError::User {
            error: FError {
                location: l,
                data: d.into(),
                kind: error.into(),
            }
        }),
}

Comma<T>: HashSet<T> = {
    <v:(<T> ",")*> <e:T> => {
        let mut result = v.into_iter().collect::<HashSet<_>>();
        result.insert(e);
        result
    },
}

match {
    "player" => "player",
    "not" => "not",
    "or" => "or",
    "and" => "and",
    "any" => "any",
    "all" => "all",
    "exists" => "exists",

    r"\d\d\d\d-\d\d-\d\d \d\d:\d\d:\d\d" => datetime,
    r"\d\d\d\d-\d\d-\d\d" => date,
    r"\w+" => word,
    r#""[^"]*""# => regex,

    _
}